如何存文字檔時,設定是用unico格式存檔的哩... 一般存文字檔時是ansi格式

有沒有人知道咩... 我試了一天了.. 若用以下面式存文字檔,是會存成unicode big endian,不是unicode FOR I:=0 TO LENGTH(TMP) DO BEGIN write(F2,TMP[i]); END; 但中文字會變亂碼.. 但textfile只接受string,各char格式..有誰能幫幫忙咩 還是有什麼轉換物件可以call... 我想要匯出文字檔是unicode格式的啦..很急...><

http://delphi.ktop.com.tw/topic.php?TOPIC_ID=32820 --- 屬於那自己生命的歌 不管是什麼顏色

我有看過這個文章,也有下載這個程式來玩 但就是不知他是怎麼做檔案轉碼的 delphi的textfile的 Writeln([ var F: Text; ] P1 [, P2, ...,Pn ] ); 是不是只能傳入string型能 我想傳WideString或widechar寫入檔案都不行耶....

找了兩篇, 您研究看看. http://groups.google.com.tw/groups?hl=zh-TW&lr=&ie=UTF-8&oe=UTF-8&th=babe5c493268a927&rnum=8 http://groups.google.com.tw/groups?hl=zh-TW&lr=&ie=UTF-8&oe=UTF-8&th=e034e6bda7d50446&rnum=70 --- 屬於那自己生命的歌 不管是什麼顏色

就 Unicode 的文字檔格式，它們都會在檔案開首加入特別的字元以識別類型：    unicode 或者叫做 unicode little endian，PC上用的都是 LE 格式，首兩個 byte 是 FF FE    unicode big endian，首兩個 byte 是 FE FF    而另一種的 UTF-8 格式，首三個 byte 是 EF BB BF    LE(litte endian) 與 BE(big endian)兩者分別很明顯，LE 儲存文字時，high byte 跟 low byte 的位置是調換，而 BE 就儲存原來的 high , low byte 的位置。    中 內碼：A4A4 UNICODE：4E2D UTF-8：E4 B8 AD 文 內碼：A4E5 UNICODE：6587 UTF-8：E6 96 87 做一個文字檔案輸入「中文」兩個字，儲存了，文字檔案的內容就是： A4 A4 A4 E5 這四個 bye 轉換成 unicode (LE) ，內容就是 FF FE 2D 4E 87 65 轉換成 unicode (BE) ，內容就是 FE FF 4E 2D 65 87 如果你的文字檔中有分行 轉換成 unicode (LE) ，內容就是 FF FE 2D 4E 0D 00 0A 00 87 65 轉換成 unicode (BE) ，內容就是 FE FF 4E 2D 00 0D 00 0A 65 87 而 UTF-8 的儲存格式，就是將一些單位元的字仍以單位元存檔，而那些雙位元都以三個或四個位元去代表 EF BB BF E4 B8 AD 0D 0A E6 96 87 由以上的例子可知，你轉換了一些字串後，要儲存成文字檔時，先要寫入兩個或三個識別位元，再可以寫入你那些已轉換的字串。 這個是我以往在網上搜查，及往後一些轉換 unicode 的經驗，如果其他人發現有錯誤，請代為補充及更正。 發表人 - tatsu 於 2004/03/11 03:35:22

引言: 有沒有人知道咩... 我試了一天了.. 若用以下面式存文字檔,是會存成unicode big endian,不是unicode FOR I:=0 TO LENGTH(TMP) DO BEGIN write(F2,TMP[i]); END; 但中文字會變亂碼.. 但textfile只接受string,各char格式..有誰能幫幫忙咩 還是有什麼轉換物件可以call... 我想要匯出文字檔是unicode格式的啦..很急...><

我想問題是 TextFile… 還有一個是 File 但是用法不一樣 要用 WINDOW 的 API var f:integer; wbuff:array[0..1] of byte; begin f := FileOpen('c:\ss.txt',fmOpenWrite); FileWrite(f,wbuff,2); 如果用 TextFile 開副檔名不是 .txt 的檔也會出錯… 發表人 - s8556026 於 2004/03/11 11:25:52

各位大大不好意思... 最新在趕其他支程式...所以還沒試大大們的方法.. 不過大大們的方法感覺得都很有希望... 不過要花時間試...只是在案子很趕又只有一個人在寫的情況下.. 有些要花時間試的技術可能要晚一點試了.... 不知有沒有好心的大大..有些小demo的,可以幫幫我哩.. 若不行我再找時間試,再來結案....真不好意思....

Hi, 試試看吧, 弟使用了 TFileStream 的方式進行操作, 將 WideString 寫入文字檔, 並配合文字檔的 LE Format 即可.     

function WriteWideString2File(filename: string; ws: WideString):Boolean;
const
  WideBOM_LSB_First      = WideChar(#$FEFF);
var
  wf: WideString;
  f: TFileStream;
  i: integer;
begin
  Result := false;
  wf := WideBOM_LSB_First;
  f:= TFileStream.Create(filename, fmCreate);
  try
    f.Write(wf[1], 2);
    for i:= 1 to length(ws) do
      f.Write(ws[i], 2);
    Result := true;
  finally
    f.Free;
  end;
end;    procedure TForm1.Button1Click(Sender: TObject);
var
  myws: WideString;
begin
  myws := 'Delphi 的 Unicode 存檔測試';
  WriteWideString2File('c:\test.txt', myws);
end;

早上再看了一下, 可以將中間的迴圈寫入的部分改得更快一些的做法, 利用 WideString 是由 WideChar 組合而成的概念來操作的, 這樣一次性的寫入應該會更快!    如:    

function WriteWideString2File(filename: string; ws: WideString):Boolean;
const
  WideBOM_LSB_First      = WideChar(#$FEFF);
var
  wf: WideString;
  f: TFileStream;
  i: integer;
begin
  Result := false;
  wf := WideBOM_LSB_First;
  f:= TFileStream.Create(filename, fmCreate);
  try
    f.Write(wf[1], 2);
    //for i:= 1 to length(ws) do
    //  f.Write(ws[i], sizeof(ws[i]));
    f.Write(PWideChar(ws)^, length(ws)*sizeof(WideChar));
    Result := true;
  finally
    f.Free;
  end;
end;

哇...感謝timhuang兄咩... 真的可以耶...謝謝你的幫忙... 真的幫我好大一個忙咩....小妹會好好努力和你學習的...^^