hi,
我在一個application上設計了一個dialog，主窗體每隔30分鐘將自動調出這個dialog要求用戶輸入一個數字。啟動這個application後，我把它最小化，然後打開其它軟體，但30分鐘後，dialog雖然是被調出來了，但總是在後方，有甚麼方法可以在計時結束後強制這個dialog彈出在并顯示在所有窗體的最上方？

我試著加入下面的代碼，但還是無效果

1) 在顯示 dialog 前，我先調用主窗體 Application.show 或 ShowWindow( Application.HANDLE, SW_RESTORE); 然後再調出 Dialog.ShowModal，但還是沒效，這個Application好像不會被還原，Dialog還是在後方顯示

2) 後來，我又inherti 了Dialog，在override的Dialog.ShowModal 裡加入了
ShowWindow( Self.ParentWindow, SW_RESTORE );
Self.BringToFront;
Self.SetFocus;

但還是沒效果。

不知你那麼快的速度結案是放棄了嗎? 還是有了答案, 著實令人十分好奇啊!

不過沒關係, 試試下列的方式

[code delphi]
function ForceForegroundWindow(hwnd: THandle): Boolean;
const SPI_GETFOREGROUNDLOCKTIMEOUT = $2000;
SPI_SETFOREGROUNDLOCKTIMEOUT = $2001;
var ForegroundThreadID: DWORD;
ThisThreadID: DWORD;
timeout: DWORD;
begin
if IsIconic(hwnd) then ShowWindow(hwnd, SW_RESTORE);
if GetForegroundWindow = hwnd then Result:= True
else begin
// Windows 98/2000 doesn't want to foreground a window when some other
// window has keyboard focus
if ((Win32Platform = VER_PLATFORM_WIN32_NT) and (Win32MajorVersion > 4)) or
((Win32Platform = VER_PLATFORM_WIN32_WINDOWS) and
((Win32MajorVersion > 4) or ((Win32MajorVersion = 4) and
(Win32MinorVersion > 0)))) then
begin
// Code from Karl E. Peterson, www.mvps.org/vb/sample.htm
// Converted to Delphi by Ray Lischner
// Published in The Delphi Magazine 55, page 16
Result:= False;
ForegroundThreadID:= GetWindowThreadProcessID(GetForegroundWindow, nil);
ThisThreadID:= GetWindowThreadPRocessId(hwnd, nil);
if AttachThreadInput(ThisThreadID, ForegroundThreadID, True) then
begin
BringWindowToTop(hwnd); // IE 5.5 related hack
SetForegroundWindow(hwnd);
AttachThreadInput(ThisThreadID, ForegroundThreadID, False);
Result:= (GetForegroundWindow = hwnd);
end;
if not Result then begin
// Code by Daniel P. Stasinski
SystemParametersInfo(SPI_GETFOREGROUNDLOCKTIMEOUT, 0, @timeout, 0);
SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(0),SPIF_SENDCHANGE);
BringWindowToTop(hwnd); // IE 5.5 related hack
SetForegroundWindow(hWnd);
SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(timeout), SPIF_SENDCHANGE);
end;
ShowWindow(hwnd,SW_SHOWNORMAL);
end
else begin
BringWindowToTop(hwnd); // IE 5.5 related hack
SetForegroundWindow(hwnd);
ShowWindow(hwnd,SW_SHOWNORMAL);
end;
Result:= (GetForegroundWindow = hwnd);
end;
end; { ForceForegroundWindow }

在你要秀出視窗的程式, 改用下列方式試試看, 或許可以解決你的問題
ForceForegroundWindow(Application.Handle);
[/code]

謝謝回复。不好意思，我是操作錯誤，想把它改回來都無法改了 :(