各位大大高手你們好: 請問有沒有指令能一次設定多個物件的同一屬性呢? 像類似 form1.setall('tedit','enabled'); 以上是小弟亂寫的.... 因為常有好多同類物件屬性要變換,寫一大串真麻煩 書上及用關鍵字也找不到有這指令,有人知道嗎? 謝~謝~~

在設計時期在表單上按住Shift鍵不放可選擇多個元件, 在Object Inspector可針對這些選擇的元件做設定 在執行時期透過Components[i]判斷元件種類,再轉型存取屬性即可

  for I := ComponentCount - 1 downto 0 do
  begin
    Temp := Components[I];
    if Temp is TButton then (Temp as TButton).Caption:='hello';
  end;

感謝pedro回答 但是 var 應該要設什麼~? 我笨笨的

Hi chuanchuan,    Pedro 大大的程式碼完整寫法如下

procedure TForm1.Button4Click(Sender: TObject);
var
    I : Integer;
    Temp : TObject;
begin
  for I := ComponentCount - 1 downto 0 do
    begin
      Temp := Components[I];
      if Temp is TButton then (Temp as TButton).Caption:='hello';
    end;
end;

另外再提供另一種寫法 Uses typInfo

procedure TForm1.Button56Click(Sender: TObject);
    Procedure SetAll(ClassName,Properties : String; Value : Variant);
        Var
            I : Integer;
            PropInfo: PPropInfo;
        BEGIN
            FOR I := 0 TO Self.ComponentCount - 1 DO
                BEGIN
                    IF LowerCase(Self.Components[I].ClassName) = Lowercase(Classname) THEN
                        BEGIN
                            PropInfo := GetPropInfo(Self.Components[I],Properties);
                            IF PropInfo <> NIL THEN
                                BEGIN
                                    TRY
                                        SetPropValue(Self.Components[I],Properties,Value);
                                    EXCEPT
                                    END;
                                END;
                        END;
                END;
        END;
begin
    SetAll('TEdit','enabled',False);
end;

---------------------------------- 小弟才疏學淺，若有謬誤尚請不吝指教 ----------------------------------

------
Fishman

感謝 Pedro 跟fishman 二位大大 可以了~~