執行檔名稱過長，在處理程序會被截掉 ex:執行檔名:Query_test.exe；處理程序只顯示Query_test.e    我有參考 http://delphi.ktop.com.tw/topic.php?TOPIC_ID=43101 刪除Query_test.exe可順利執行，但碰到Query_test.e 且os:Win2000就會完蛋 因每次欲刪除的執行檔不同，固無法寫死；且客戶端電腦os也不可能更換 如何由"處理程序＼影像名稱"知道"應用程式＼工作"並將它結束??

引言: 執行檔名稱過長，在處理程序會被截掉 ex:執行檔名:Query_test.exe；處理程序只顯示Query_test.e

這部分的問題說明能否再清楚一點 ＠瞭解越多.懂得越少＠

在win2000下由程式刪除Query_test.exe都失敗,因在"工作管理員＼處理程序＼影像名稱" 只顯示Query_test.e(後面的"xe"會被截掉) 如何由"工作管理員＼處理程序＼影像名稱"知道"工作管理員＼應用程式＼工作"並將它結束??

既然你可以確定執行檔名  並不一定要使用kill by title title 只是取得Process Handle / window handle的途徑之一    直接利用該檔名(影像名稱)取得其Process Handle 一樣可以TerminateProcess    以下這些函式可以參考 【Delphi】【發表】Program Name、PID、Window Handle、hProcess 的轉換函式 http://delphi.ktop.com.tw/topic.php?TOPIC_ID=61654    

function GetPIDByProgramName(const APName: string; bWithOutPath: Boolean =
  True): THandle;
var
  isFound: boolean;
  AHandle, AhProcess: THandle;
  ProcessEntry32: TProcessEntry32;
  APath: array[0..MAX_PATH] of char;
begin
  try
    Result := 0;
    AHandle := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
    ProcessEntry32.dwSize := Sizeof(ProcessEntry32);
    isFound := Process32First(AHandle, ProcessEntry32);        while isFound do
    begin
      AhProcess := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ,
        false, ProcessEntry32.th32ProcessID);
      GetModuleFileNameEx(AhProcess, 0, @APath[0], sizeof(APath));          if (UpperCase(StrPas(APath)) = UpperCase(APName)) or
        (UpperCase(StrPas(ProcessEntry32.szExeFile)) = UpperCase(APName)) or
        (bWithOutPath and (
        (UpperCase(ExtractFileName(StrPas(APath))) =
        UpperCase(ExtractFileName(APName))) or
        //for partial filename without path
        (UpperCase(ExtractFileName(StrPas(ProcessEntry32.szExeFile))) =
        UpperCase(ExtractFileName(APName)))
        )
        ) then //for partial filename without path
      begin
        Result := ProcessEntry32.th32ProcessID;
        break;
      end;
      isFound := Process32Next(AHandle, ProcessEntry32);
      CloseHandle(AhProcess);
    end;
  finally
    CloseHandle(AHandle);
  end;
end;    function GetProcessHndByPID(const hAPID: THandle): THandle;
var
  AhProcess: THandle;
begin
  if hAPID <> 0 then
  begin
    AhProcess := OpenProcess(PROCESS_ALL_ACCESS, false, hAPID);
    Result := AhProcess;
    //Only close Handle on finish operation, CloseHandle would make the AhProcess not available
  end
  else
    Result := 0;
end;    function GetProcessHndByProgramName(const APName: string; bWithOutPath: Boolean = True): THandle;
begin
  if APName <> '' then
    Result := GetProcessHndByPID(GetPIDByProgramName(APName))
  else
    Result := 0;
end;    
procedure TForm1.Button1Click(Sender: TObject);
var
  hProcess:THandle;
begin
  hProcess:=GetProcessHndByProgramName('notepad.exe', False);
  if hProcess>0 then
    TerminateProcess(hProcess,0);
end;    

＠瞭解越多.懂得越少＠