各位版大,,小弟目前正在寫1只小型行動版資料庫程式...!!須要硬体(品牌)名稱..例如(oppo,htc,asus..等)請問有何方法..可以取得???謝謝!!

------
艾瑞克

 

unit uOSVersionAndLocale;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls,
  FMX.Controls.Presentation, FMX.ScrollBox, FMX.Memo, FMX.Platform
{$IFDEF Android}
  ,Androidapi.JNI.Os  //TJBuild
  ,Androidapi.Helpers // StringToJString
{$ENDIF}
{$IFDEF IOS}
  ,iOSapi.UIKit
  ,Posix.SysSysctl
  ,Posix.StdDef
{$ENDIF}
  ;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    ToolBar1: TToolBar;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
{$IFDEF IOS}
    function GetDeviceModelString: String;
{$ENDIF}
    { private 宣言 }
  public
    { public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

{$IFDEF IOS}
function TForm1.GetDeviceModelString: String;
var
  Size: size_t;
  DeviceModelBuffer: array of Byte;
begin
  sysctlbyname('hw.machine', nil, @Size, nil, 0);

  if Size > 0 then
  begin
    SetLength(DeviceModelBuffer, Size);
    sysctlbyname('hw.machine', @DeviceModelBuffer[0], @Size, nil, 0);
    Result := UTF8ToString(MarshaledAString(DeviceModelBuffer));
  end
  else
    Result := EmptyStr;
end;
{$ENDIF}

procedure TForm1.Button1Click(Sender: TObject);
var
  OSVersion: TOSVersion;
  OSLang: String;
  LocaleService: IFMXLocaleService;

  ModelName: String;
begin
  ModelName := 'unknown';
{$IFDEF Android}
  ModelName := JStringToString(TJBuild.JavaClass.MODEL);
{$ENDIF}
{$IFDEF IOS}
  ModelName := GetDeviceModelString;
{$ENDIF}

  Memo1.Lines.Add(Format('ModelName=%s', [ ModelName ] ));
  Memo1.Lines.Add(Format('OSName=%s', [OSVersion.Name]));
  Memo1.Lines.Add(Format('Platform=%d', [Ord(OSVersion.Platform)]));
  Memo1.Lines.Add(Format('Version=%d.%d', [OSVersion.Major,OSVersion.Minor]));

  OSLang := '';
  if TPlatformServices.Current.SupportsPlatformService(IFMXLocaleService, IInterface(LocaleService)) then
  begin
    OSLang := LocaleService.GetCurrentLangID();

    // if set Japanese on Android, LocaleService returns "jp", but other platform returns "ja"
    // so I think it is better to change "jp" to "ja"
    if (OSLang = 'jp') then OSLang := 'ja';
  end;
  Memo1.Lines.Add(Format('Lang=%s', [ OSLang ] ));

end;

end.

------
------------------------
博采眾家之長,奉獻綿薄之力
------------------------

// 下面的Brand與Manufacturer應該是你要的
Memo1.Lines.Add('BRAND: ' JStringToString(TJBuild.JavaClass.BRAND)) ;
Memo1.Lines.Add('MANUFACTURER: ' JStringToString(TJBuild.JavaClass.MANUFACTURER)) ;

Memo1.Lines.Add('DEVICE: ' JStringToString(TJBuild.JavaClass.DEVICE));
Memo1.Lines.Add('getRadioVersion: ' JStringToString(TJBuild.JavaClass.getRadioVersion));

Memo1.Lines.Add('DISPLAY: ' JStringToString(TJBuild.JavaClass.DISPLAY)) ;
Memo1.Lines.Add('BOARD: ' JStringToString(TJBuild.JavaClass.BOARD)) ;
Memo1.Lines.Add('BOOTLOADER: ' JStringToString(TJBuild.JavaClass.BOOTLOADER)) ;
Memo1.Lines.Add('HARDWARE: ' JStringToString(TJBuild.JavaClass.HARDWARE)) ;
Memo1.Lines.Add('ID: ' JStringToString(TJBuild.JavaClass.ID)) ;
Memo1.Lines.Add('RADIO: ' JStringToString(TJBuild.JavaClass.RADIO)) ;
===================引 用 艾瑞克 文 章===================
各位版大,,小弟目前正在寫1只小型行動版資料庫程式...!!須要硬体(品牌)名稱..例如(oppo,htc,asus..等)請問有何方法..可以取得???謝謝!!

------
------------------------
博采眾家之長,奉獻綿薄之力
------------------------

編輯記錄

謝謝...h@visli 大力 協助!!!

------
艾瑞克