現在 FORM 上有多個 Pagecontrol A, Pagecontrol B, Pagecontrol C
每個 Pagecontrol A/B/C 下,又有 多個 Pagecontrol

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.

請問~
假如改設在onShow呢?
又或者~
在Form開完後
弄個等待視窗來做載入呢?

我個人在猜...
值之所以會有錯誤
"可能"是元件還沒被建立完成?
就如同您提到的一樣

小弟只是個小小新手
如發言有誤
請包涵~^^

===================引 用 老大仔 文 章===================
請問~
假如改設在onShow呢? 不行, 非 ACTIVE (FOCUS) 的 TABSHEET ,裡面的元件值都不是 "載入" 的值
又或者~
在Form開完後
弄個等待視窗來做載入呢? 這想法不錯,只是網友不知有其它更好的方法....

我個人在猜...
值之所以會有錯誤
"可能"是元件還沒被建立完成?
就如同您提到的一樣

小弟只是個小小新手
如發言有誤
請包涵~^^

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.

[code delphi]
unit fMain;

interface

uses
Windows,
TypInfo,
SysUtils,
Classes,
Controls,
Forms,
StdCtrls,
ComCtrls;

type
//參考來源: http://www.swissdelphicenter.ch/torry/showcode.php?id=2436
TUserConfig = class(TObject)
private
function IsProperty(Obj: TObject; sProp: string): Boolean;
function SetProperty(Obj: TObject; sProp: string; vValue: Variant): Boolean;
function HasAncestor(Child: TComponent; _name: string): Boolean;
public
function SaveToFile(Component: TComponent; fn: string): Boolean;
function LoadFromFile(Component: TComponent; fn: string): Boolean;
end;

TfrmMain = class(TForm)
PageControlA: TPageControl;
TabSheet1: TTabSheet;
Edit1: TEdit;
Edit2: TEdit;
Edit3: TEdit;
TabSheet2: TTabSheet;
CheckBox1: TCheckBox;
ListBox1: TListBox;
ComboBox1: TComboBox;
Button1: TButton;
Button2: TButton;
procedure FormCreate(Sender: TObject);
procedure FormClose(Sender: TObject; var Action: TCloseAction);
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
private
X: TUserConfig;
end;

var
frmMain: TfrmMain;

implementation

{$R *.dfm}

function TUserConfig.IsProperty(Obj: TObject; sProp: string): Boolean;
var
i,n: Integer;
plList: TPropList;
begin
Result := False;

i := GetPropList(
PTypeInfo(Obj.ClassInfo),
[Low(TTypeKind)..High(TTypeKind)],
@plList);

n := 0;
while n begin
Result := plList[n].Name=sProp;
if Result then Break else Inc(n);

end;

end;

function TUserConfig.SetProperty(Obj: TObject; sProp: string; vValue: Variant): Boolean;
begin
Result := IsProperty(Obj,sProp);
if Result then SetPropValue(Obj,sProp,vValue);
end;

function TUserConfig.HasAncestor(Child: TComponent; _name: string): Boolean;
var
C: TComponent;
begin
Result := False;

C := Child;
while C.HasParent do
begin
C := C.GetParentComponent;
if C.Name<>_name then Continue;
Result := True;
Break;
end;


end;

function TUserConfig.SaveToFile(Component: TComponent; fn: string): Boolean;
var
I: Integer;
S: string[255];
C,O: TComponent;
F: TFileStream;
begin
C := Component;
while C.HasParent do
begin
C := C.GetParentComponent;
end;

F := TFileStream.Create(fn,fmCreate);
try
for I := 0 to C.ComponentCount-1 do
begin
O := C.Components[I];
if not (O is TControl) then Continue;
if not HasAncestor(O,Component.Name) then Continue;
S := O.Name;
F.Write(S,Length(S) 1);
F.WriteComponent(O);
end;
Result := True;
finally
FreeAndNil(F);
end;

end;

function TUserConfig.LoadFromFile(Component: TComponent; fn: string): Boolean;
var
n: Integer;
C,O: TComponent;
F: TFileStream;
sName: string[255];
iName: Integer;
begin
Result := False;
if not FileExists(fn) then EXIT;

C := Component;
while C.HasParent do
begin
C := C.GetParentComponent;
end;

F := TFileStream.Create(fn,fmOpenRead);
try
F.Position := 0;
while F.Position begin
F.Read(sName[0], 1);
iName := Byte(sName[0]);
F.Read(sName[1],iName);
for n := 0 to C.ComponentCount-1 do
begin
O := C.Components[n];
if O.Name<>sName then Continue;
SetProperty(O,'Checked', False);
F.ReadComponent(O);
Break;
end;
end;
finally
FreeAndNil(F);
end;

end;

procedure TfrmMain.FormCreate(Sender: TObject);
begin
X := TUserConfig.Create;
X.LoadFromFile(PageControlA,'ABC.DAT');
end;

procedure TfrmMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
X.SaveToFile(PageControlA,'ABC.DAT');
FreeAndNil(X);
end;

procedure TfrmMain.Button1Click(Sender: TObject);
begin
ListBox1.Items.Add(IntToStr(Random(1000)));
ComboBox1.Items.Add(IntToStr(Random(1000)));
end;

procedure TfrmMain.Button2Click(Sender: TObject);
begin

if ListBox1.Items.Count>0 then
ListBox1.Items.Delete(Random(ListBox1.Items.Count));

if ComboBox1.Items.Count>0 then
ComboBox1.Items.Delete(Random(ComboBox1.Items.Count));

end;

end.
[/code]

 感謝 jow 兄的範例, 這種寫法算是 "高度技巧",不容易看懂
不過在單層的 PageControl 可以(範例 1),多層 PageContril 上(範例 2,) 還需修改

另外範例 3. 是我目前的做法,很 "土" 及 直覺的寫法
很奇怪,用此範例3,在 FormCreate 時,他是可以還原全部的值,且 edit 都有更新

我出問題的程式,欄位超過百個,有些欄位無法更新正確的值(用 FormCreate 自動載入)
但用 Button 載入,也可以更新正確值.

附上 範例 1,2,3 ;
1 -> 是 jow 兄的 ,
2-> 是多個 PageControl
3-> 一般寫法(我自己寫的)
請到 "會員作品區 " 下載
http://delphi.ktop.com.tw/board.php?cid=31&fid=79&tid=104879

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.

編輯記錄

end.

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.

[code delphi]
unit fMain;
interface

uses
Windows,
SysUtils,
Classes,
Controls,
Forms,
StdCtrls,
ExtCtrls,
ComCtrls;

type
TUserConfig = class(TObject)
private
F_Owner: TForm;
function ControlType(O: TComponent): Integer;
public
constructor Create(AOwner: TForm);
procedure SaveToFile2(fn: string);
procedure LoadFromFile2(fn: string);
end;

TfrmMain = class(TForm)
PageControlA: TPageControl;
PageControl1: TPageControl;
PageControl2: TPageControl;
PageControl3: TPageControl;
PageControl4: TPageControl;
TabSheet1: TTabSheet;
TabSheet2: TTabSheet;
TabSheet3: TTabSheet;
TabSheet4: TTabSheet;
TabSheet5: TTabSheet;
TabSheet6: TTabSheet;
Edit1: TEdit;
Edit2: TEdit;
Edit4: TEdit;
ListBox1: TListBox;
ListBox2: TListBox;
ComboBox1: TComboBox;
ComboBox2: TComboBox;
CheckBox1: TCheckBox;
RadioGroup1: TRadioGroup;
procedure FormCreate(Sender: TObject);
procedure FormClose(Sender: TObject; var Action: TCloseAction);
private
X: TUserConfig;
end;

var
frmMain: TfrmMain;

implementation

{$R *.dfm}

constructor TUserConfig.Create(AOwner: TForm);
begin
inherited Create;
F_Owner := AOwner;
end;

function TUserConfig.ControlType(O: TComponent): Integer;
begin
Result := -1;
if O is TEdit then Result := 0
else if O is TListBox then Result := 1
else if O is TComboBox then Result := 2
else if O is TCheckBox then Result := 3
else if O is TRadioGroup then Result := 4
else if O is TPageControl then Result := 5;
end;

procedure TUserConfig.LoadFromFile2(fn: string);
var
L,M: TStringList;
n,I,K: Integer;
O: TComponent;
S: string;
begin

if not FileExists(fn) then EXIT;

L := TStringList.Create;
M := TStringList.Create;
try
M.Delimiter := ';';
L.LoadFromFile(fn);
for I := 0 to F_Owner.ComponentCount-1 do
begin
O := F_Owner.Components[I];
n := ControlType(O);
if n=-1 then Continue;

M.DelimitedText := L.Values[UpperCase(O.Name)];
for K := 0 to M.Count-1 do
begin
S := Trim(M[K]);
case n of
0:
case K of
0: TEdit(O).Text := S;
end;
1:
case K of
0: TListBox(O).Items.CommaText := S;
1: TListBox(O).ItemIndex := StrToIntDef(S,-1);
end;
2:
case K of
0: TComboBox(O).Items.CommaText := S;
1: TComboBox(O).ItemIndex := StrToIntDef(S,-1);
end;
3:
case K of
0: TCheckBox(O).Checked := S='1';
end;
4:
case K of
0: TRadioGroup(O).Items.CommaText := S;
1: TRadioGroup(O).ItemIndex := StrToIntDef(S,-1);
end;
5:
case K of
0: TPageControl(O).ActivePageIndex := StrToIntDef(S,-1);
end;
end;
end;
end;
finally
FreeAndNil(M);
FreeAndNil(L);
end;

end;

procedure TUserConfig.SaveToFile2(fn: string);
var
n,I: Integer;
L,M: TStringList;
O: TComponent;
begin
L := TStringList.Create;
M := TStringList.Create;
try
M.Delimiter := ';';
for I := 0 to F_Owner.ComponentCount-1 do
begin
O := F_Owner.Components[I];
n := ControlType(O);
if n = -1 then Continue;

M.Clear;
case n of
0: with TEdit(O) do M.Add(Text);
1:
with TListBox(O) do
begin
M.Add(Items.CommaText);
M.Add(IntToStr(ItemIndex));
end;
2:
with TComboBox(O) do
begin
M.Add(Items.CommaText);
M.Add(IntToStr(ItemIndex));
end;
3: with TCheckBox(O) do M.Add(IntToStr(Ord(Checked)));
4:
with TRadioGroup(O) do
begin
M.Add(Items.CommaText);
M.Add(IntToStr(ItemIndex));
end;
5: with TPageControl(O) do M.Add(IntToStr(ActivePageIndex));
end;

if M.DelimitedText<>'' then
begin
L.Values[UpperCase(O.Name)] := M.DelimitedText;
end;


end;

if L.Count=0 then DeleteFile(fn) else L.SaveToFile(fn);

finally
FreeAndNil(M);
FreeAndNil(L);
end;

end;

{ TfrmMain }

procedure TfrmMain.FormCreate(Sender: TObject);
begin
X := TUserConfig.Create(Self);
X.LoadFromFile2('WXYZ.TXT');
end;

procedure TfrmMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
X.SaveToFile2('WXYZ.TXT');
FreeAndNil(X);
end;


end.
[/code]

 JOW 太強了,感恩 !!

前輩您好人做到底....可否上傳到作品區,方便下載...

謝謝您

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.

高高手jow前輩已將範例放到下面連結供下載 ^^
http://delphi.ktop.com.tw/board.php?cid=31&fid=79&tid=104880

===================引 用 ANDY8C 文 章===================
JOW 太強了,感恩 !!

前輩您好人做到底....可否上傳到作品區,方便下載...

謝謝您

編輯記錄

剛用 jow 的範例測試,加入 UpDown 的功能

發現一個 EDIT 的小問題
若 EDIT 的 增/減是透過 UpDown 來進行
在程式執行時後(第一個畫面),螢幕的此 EDIT 值都顯示
UpDown MIN 值(不會顯示上次的存檔值)

若用按鍵 "重新載入" ,才會看到上次EDIT 存檔值
這好像不是上次我說的 Focus 問題,
不知是 EDIT 或 UPDOWN 的那個 Properties 要設定
還是有其它方式可以改善.....
已附上 測試的程式於 "作品區"

TEST_18.ZIP



謝謝您

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.

[code delphi]
function TUserConfig.ControlType(O: TComponent): Integer;
begin
Result := -1;
if O is TEdit then Result := 0
else if O is TListBox then Result := 1
else if O is TComboBox then Result := 2
else if O is TCheckBox then Result := 3
else if O is TRadioGroup then Result := 4
else if O is TPageControl then Result := 5
else if O is TUpDown then Result := 6;
end;

procedure TUserConfig.LoadFromFile2(fn: string);
var
L,M: TStringList;
n,I,K: Integer;
O,P: TComponent;
S: string;
begin
{省略...}

case n of
{省略...}
6:
begin
case K of
0: TUpDown(O).Max := StrToIntDef(S,100);
1: TUpDown(O).Min := StrToIntDef(S,0);
2: TUpDown(O).Position := StrToIntDef(S,0);
end;
P := TUpDown(O).Associate;
case ControlType(P) of
0: TEdit(P).Text := IntToStr(TUpDown(O).Position);
end;
end;
{省略...}

end;
end;

procedure TUserConfig.SaveToFile2(fn: string);
var
n,I: Integer;
L,M: TStringList;
O: TComponent;
begin
{省略...}

case n of
{省略...}
6:
with TUpDown(O) do
begin
M.Add(IntToStr(Max));
M.Add(IntToStr(Min));
M.Add(IntToStr(Position));
end;
end;
{省略...}

end;

[/code]

編輯記錄

 jow 前輩,剛測試一下, ok 了
簡潔的程式, 要功力深厚的人才能完成.

感恩

謝謝您

------
---------------------------------------
偶爾才來 KTOP ,交流條碼問題,在 FB [條碼標籤達人] 社團留言,感恩.