先問問怎樣寫回傳array of string的問題

因為不能像這樣：
function ret_arr():array of string
那麼應該怎樣寫呢？

------
獨學無友則孤陋寡聞，相識滿天下能知天下事
小弟是來自香港的～～多多指教

試試~

[code delphi]
unit fMain;

interface

uses
Classes, Controls, StdCtrls, SysUtils, Forms;

type

TArrayOfString = array of string;

TForm1 = class(TForm)
Button1: TButton;
ListBox1: TListBox;
Button2: TButton;
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
private
public
function GetArrayOfString(Len: Integer): TArrayOfString; overload;
function GetArrayOfString(var A: TArrayOfString; Len: Integer): Boolean; overload;
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

function TForm1.GetArrayOfString(Len: Integer): TArrayOfString;
var
I: Integer;
begin
Result := nil;
if Len > 0 then
begin
SetLength(Result, Len);
for I := 0 to Length(Result)-1 do
Result[I] := Format('%5.5d', [I]);
end;
end;

function TForm1.GetArrayOfString(var A: TArrayOfString; Len: Integer): Boolean;
begin
A := GetArrayOfString(Len);
Result := A <> nil;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
I: Integer;
A: TArrayOfString;
begin
A := GetArrayOfString(10);
if A <> nil then
try
ListBox1.Clear;
for I := 0 to Length(A)-1 do
ListBox1.Items.Add(A[I]);
finally
A := nil;
end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
I: Integer;
A: TArrayOfString;
begin
if GetArrayOfString(A, 10) then
try
ListBox1.Clear;
for I := 0 to Length(A)-1 do
ListBox1.Items.Add(A[I]);
finally
A := nil;
end;
end;

end.

[/code]

編輯記錄

還有一個問題，如果是將這個回傳值，給另一個form 的array of string又要怎樣做呢？

------
獨學無友則孤陋寡聞，相識滿天下能知天下事
小弟是來自香港的～～多多指教

你可以將GetArrayOfString()提為公用的函式, 
只要uses該單元即可叫用了...

建議使用TStrings
取代Array of String!!

Oh~I See

------
獨學無友則孤陋寡聞，相識滿天下能知天下事
小弟是來自香港的～～多多指教