請教大家
我有一個檔案叫PM.DAT
內容如下：底線代表空白,XXXXXXX是註解不讀
__1_ XXXXXXX
__0_ XXXXXXX
_150 XXXXXXX
_100 XXXXXXX
_15_ XXXXXXX
__8_ XXXXXXX
_60. XXXXXXX
__1. XXXXXXX
0.01_ XXXXXXX
PARAMETRIC MODEL XXXXXXX
____1.0___ ____1.0___ ____0.0___ XXXXXXX
____4.____ ____60.___ ____6.0___ ____0.____ XXXXXXX

我如何先讀到前面九個數值到某些變數,做完一些運算
再讀PARAMETRIC MODEL這個字串,做一些判斷後
再一次讀進三個數值到某些變數,做完一些運算
再一次讀進四個數值到某些變數,做運算
像這種讀檔,程式要怎麼寫壓??

[code delphi]
unit fMain;

interface

uses
Forms, Classes, Controls, StdCtrls;

type
TArrayOfSingle = array of Single;

TForm1 = class(TForm)
Button1: TButton;
ListBox1: TListBox;
procedure Button1Click(Sender: TObject);
private
function SepValueStr(var S, ValueStr: string): Boolean;
function ExtractValue(L: TStringList; Start: Integer): TArrayOfSingle;
function GetModelValue(L: TStringList; P, ItemCount: Integer): TArrayOfSingle;
end;

var
Form1: TForm1;

implementation

uses SysUtils;

{$R *.dfm}

function TForm1.SepValueStr(var S, ValueStr: string): Boolean;
var
I: Integer;
begin
I := Pos(#$20, S);
Result := I > 0;
if Result then
begin
ValueStr := Trim(Copy(S,1,I-1));
S := Trim(Copy(S, I, Length(S)-I));
end;
end;

function TForm1.ExtractValue(L: TStringList; Start: Integer): TArrayOfSingle;
const
VALUE_END = 'PARAMETRIC';
var
S, T: string;
I, K: Integer;
begin
SetLength(Result, L.Count);
K := 0;
for I := Start to L.Count-1 do
begin
S := Trim(L[I]);
if Pos(VALUE_END, UpperCase(S)) > 0 then Break;
if SepValueStr(S, T) then
begin
Result[K] := StrToFloat(T);
Inc(K);
end;
end;
SetLength(Result, K);
end;

function TForm1.GetModelValue(L: TStringList; P, ItemCount: Integer): TArrayOfSingle;
var
S, T: string;
I: Integer;
begin
SetLength(Result, ItemCount);

I := 0;
S := Trim(L[P]);
repeat
if SepValueStr(S, T) then
begin
Result[I] := StrToFloat(T);
Inc(I);
end
else Break;
until I = ItemCount;
SetLength(Result, I);
end;

procedure TForm1.Button1Click(Sender: TObject);
const
FILE_NAME = 'PM.TXT';
var
I, K: Integer;
S: string;
L: TStringList;
V: array[0..2] of TArrayOfSingle;
begin
if FileExists(FILE_NAME) then
begin
L := TStringList.Create;
try
L.LoadFromFile(FILE_NAME);
V[0] := ExtractValue(L, 0);
I := Length(V[0]);
S := L[I];
Inc(I); V[1] := GetModelValue(L, I, 3);
Inc(I); V[2] := GetModelValue(L, I, 4);

//Show Extraction Result
L.Clear;
for K := 0 to Length(V)-1 do
begin
for I := 0 to Length(V[K])-1 do
L.Add(Format('%.2f', [V[K][I]]));
if K = 0 then L.Add(S);
end;
ListBox1.Items.Text := L.Text;
//Show Extraction Result.

finally
FreeAndNil(L);
end;
end;

end;

end.

[/code]

編輯記錄

jow您好：

感謝您提供給我的程式碼，我試用了您寫的程式碼完美的呈現我需要的讀檔方式，
接下來就是加上我需要的計算過程，再次感謝您..thx..

編輯記錄