打算做個logo出來~但是抬頭  就是藍色那一條!?
不知道要如何關掉~

請問一下該如何解決~!?
謝謝

通常都是自行繪製一個圖片, 程式只顯示此一圖片的外圍區域.
使用關鍵字去搜查尋文章吧,

[code cpp]
void __fastcall TForm1::FormCreate(TObject *Sender)
{
HRGN rethRgn;
rethRgn=CreateRoundRectRgn(0,0,Form1->Width,Form1->Height,50,50); //圓角矩形
SetWindowRgn(Form1->Handle,rethRgn,True);
}
[/code]

------
FPGA驗證, FPGA開發平台, http://smims.com

 程式只顯示此一圖片的外圍區域.!???這句我不太懂~

目前我圖做好了，form方面autosize選ture基本上 這個form就是我的圖了，就差上面!~的抬頭(放大，縮小，結束的那一列)



===================引 用 ikk 文 章===================
通常都是自行繪製一個圖片, 程式只顯示此一圖片的外圍區域.
使用關鍵字去搜查尋文章吧,

編輯記錄

BorderStyle 設定成 bsNone...

謝謝你的回答~ 
現在如果是子視窗的話 mdichild~BorderStyle 設定成 bsNone 會沒有效用
請問還有其他的方法嗎!?
===================引 用 jow 文 章===================
BorderStyle 設定成 bsNone...

比較好奇
你想做的是類似程式起始的載入畫面嗎?

恩 有的 第一部分 就是所謂的logo 就是~~~程式起始的載入畫面~~

第二部分的話 想幫主程式設計較美觀的起始畫面
===================引 用 hipig 文 章===================
比較好奇
你想做的是類似程式起始的載入畫面嗎?

程式起始載入畫面

謹供參考...

[code delphi]
program Test057;

uses
Forms,
fMain in 'UNIT\fMain.pas' {frmMain},
fSplash in 'UNIT\fSplash.pas' {frmSplash};

{$R *.res}

begin

Application.Initialize;


//frmSplash 宣告在 fSplash.pas
frmSplash := TfrmSplash.Create(Application);

//然後,在TfrmMain.OnActivate()時,關閉並釋放frmSplash
Application.CreateForm(TfrmMain, frmMain);

Application.Run;

end.

[/code]

[code delphi]
unit fMain;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs;

type
TfrmMain = class(TForm)
procedure FormActivate(Sender: TObject);
procedure FormCreate(Sender: TObject);
private
public
end;

var
frmMain: TfrmMain;

implementation

uses fSplash;

{$R *.dfm}

procedure TfrmMain.FormCreate(Sender: TObject);
var
I: Integer;
begin
//Initial(模擬載入進度)
if frmSplash <> nil then
begin
frmSplash.Gauge1.MinValue := 0;
frmSplash.Gauge1.MaxValue := 99;
for I := 0 to 99 do
begin
frmSplash.Gauge1.Progress := I;
Application.ProcessMessages;
Sleep(50);
end;
end;
end;

procedure TfrmMain.FormActivate(Sender: TObject);
begin
if frmSplash <> nil then
begin
frmSplash.Close;
FreeAndNil(frmSplash);
end;
end;

end.

[/code]


[code delphi]
unit fSplash;

interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, Gauges;

type
TfrmSplash = class(TForm)
Gauge1: TGauge;
procedure FormCreate(Sender: TObject);
procedure FormPaint(Sender: TObject);
public
procedure DrawBackImage(fn: string);
end;

var
frmSplash: TfrmSplash;

implementation

{$R *.dfm}

procedure TfrmSplash.FormCreate(Sender: TObject);
begin
BorderStyle := bsNone;
FormStyle := fsStayOnTop;
Position := poScreenCenter;
Gauge1.Top := ClientHeight - Gauge1.Height - 10;
Show();
Update();
end;

procedure TfrmSplash.FormPaint(Sender: TObject);
begin
DrawBackImage('C:\TEST.BMP');
end;

procedure TfrmSplash.DrawBackImage(fn: string);
var
b: TBitmap;
begin
if FileExists(fn) then
begin
b := TBitmap.Create;
try
b.LoadFromFile(fn);
Canvas.Lock;
try
Canvas.StretchDraw(ClientRect,b);
finally
Canvas.Unlock;
end;
finally
FreeAndNil(b);
end;
end;
end;

end.

[/code]

程式碼下載:
http://delphi.ktop.com.tw/download.php?download=upload/47e31382e8f2f_Test057.zip


啊! 弄錯工具了!! >''<

編輯記錄